*EL2180 Macromodel 每 also used for the following related devices
*EL2186 (EL2186 with disable feature 每 disable feature is not modeled)
*EL2280, EL2286 (dual channel versions)
*EL2386 (triple channel version)
*EL2480 (quad channel version)
*
*Revision History: Rev. 2, March, 2011 by Jian Wang
*Added/Correcting Input Noise (by Jian Wang)
*Intended use: This Pspice Macromodel is intended to give typical DC and AC 
*performance characteristics under a wide range of external circuit configurations 
*using compatible simulation platforms 每 such as iSim PE. 
*
*Device performance features supported by this model:
*Typical, room temp., nominal power supply voltages used to produce the following characteristics
*Open and closed loop I/O impedances
*Open loop gain and phase
*Closed loop bandwidth and frequency response peaking under different external conditions
*Loading effects on closed loop frequency response
*Input noise terms including 1/f effects
*Slew rate
*Input and Output Headroom limits to I/O voltage swing
*Supply current at nominal specified supply voltages
*Nominal input DC error terms (1/3 of specified data sheet test or specified limits 
*每 intended to give 1考 error term on one polarity)
*Load current reflected into the power supply current
*
*Device performance features NOT supported by this model:
*Harmonic distortion effects
*Composite video differential gain and phase errors
*Output current limiting (if any)
*Disable operation (if any)
*Thermal effects and/or over temperature parameter variation
*Limited performance variation vs. supply voltage is modeled
*Part to part performance variation due to normal process parameter spread
*Any performance difference arising from different packaging
*
*LICENSE STATEMENT
*The information in this SPICE model is protected under
*the United States copyright laws. Intersil Corporation hereby
*grants users of this macro-model hereto referred to
*as "Licensee", a nonexclusive, nontransferable license to use
*this model as long as the Licensee abides by the terms of this agreement.
*Before using this macro-model, the Licensee should read this license.
*If this Licensee does not accept these terms,
*permission to use the model is not granted.
*The Licensee may not sell, loan, rent, or license the macro-model,
*in whole, in part, or in modified form, to anyone
*outside the Licensee's company. The Licensee may
*modify the macro-model to suit his/her specific applications,
*and the Licensee may make copies of this macro-model for use within 
*their company only.
*This macro-model is provided "AS IS, WHERE IS, AND WITH NO
*WARRANTY OF ANY KIND EITHER EXPRESSED OR IMPLIED, INCLUDING BUT
*NOT LIMITED TO ANY IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
*FOR A PARTICULAR PURPOSE."
*In no event will Intersil be liable for special, collateral,
*incidental, or consequential damages in connection with or arising
*out of the use of this macro-model. Intersil reserves the right to 
*make changes to the product and the macro-model without prior notice.
*
* 
* Connections:        +input
*                       |  -input
*                       |    | +Vsupply
*                       |    |    | -Vsupply
*                       |    |    |    |  output
*                       |    |    |    |    |
.subckt EL2180          3    2    7    4    6
*
*Voltage Noise
D_DN1         102 101 DN 
D_DN2         104 103 DN 
R_R21         0 101  5 
R_R22         0 103  5
E_EN          300 3 101 103 1
V_V15         102 0 2Vdc
V_V16         104 0 2Vdc
*Current Noise
G_Gn1         3 0 NI1 0 1
G_Gn2         2 0 NI2 0 1
R_R23         0 NI1  0.0004 
R_R24         0 NI1  0.0004
R_R25         0 NI2  0.036 
R_R26         0 NI2  0.036
* Input Stage 
*
e1  10 0 300 0 1.0
vis 10 9 0V
h2   9 12 vxx 1.0
r1   2 11 400  
l1  11  12 25nH
iinp 300  0 1.5uA   
iinm 2  0 3uA
r12  300  0 2Meg
*
* Slew Rate Limiting
*
h1 13  0 vis 600
r2 13 14 1K
d1 14  0  dclamp
d2  0 14  dclamp 
*
* High Frequency Pole  
*
e2 30 0 14 0 0.00166666666
l3 30 17 150nH
c5 17 0 0.8pF
r5 17 0 165
*
* Transimpedance Stage
* 
g1 0 18 17 0 1.0
rol 18 0 450K 
cdp 18 0 0.675pF  
*
* Output Stage 
*
q1 4 18 19 qp 
q2 7 18 20 qn 
q3 7 19 21 qn 
q4 4 20 22 qp 
r7 21 6  4
r8 22 6  4
ios1 7 19 1mA
ios2 20 4 1mA
*
* Supply Current
*
ips 7 4 0.2mA
*
* Error Terms
* 
ivos 0 23 0.2mA
vxx 23  0 0V
e4  24 0 300 0 1
e5  25 0 7 0 1.0
e6  26 0 4 0 -1.0
r9  24 23 316
r10 25 23 3.2K
r11 26 23 3.2K 
*
* Models
*
.model qn npn(is=5e-15 bf=200 tf=0.01nS)
.model qp pnp(is=5e-15 bf=200 tf=0.01nS)
.model dclamp d(is=1e-30 ibv=0.266 bv=0.71v n=4)
.model DN D(KF=3E-11 AF=1)
.ends EL2180